refactor: centralise home-manager configs in system configs

configs/programs/ags.nix

@@ -0,0 +1,22 @@
+{ inputs, pkgs, ... }:
+{
+  home-manager.users.rafiq = {
+    imports = [ inputs.ags.homeManagerModules.default ];
+
+    # Expose the cli tools to the home environment
+    home.packages = [ inputs.ags.packages.${pkgs.stdenv.hostPlatform.system}.io ];
+
+    programs.ags = {
+      enable = true;
+      configDir = ./ags; # ~/.config/ags
+      systemd.enable = false;
+
+      # The module only includes the core astal3, astal4 and astal-io libraries
+      extraPackages = with pkgs; [
+        # add packages to runtime
+        # inputs.ags.packages.${pkgs.system}.battery
+        # fzf
+      ];
+    };
+  };
+}

configs/programs/clipse.nix

@@ -0,0 +1,9 @@
+{
+  home-manager.users.rafiq = {
+    services.clipse = {
+      enable = true;
+      historySize = 1000;
+      imageDisplay.type = "kitty";
+    };
+  };
+}

configs/programs/comma.nix

@@ -0,0 +1,11 @@
+{ inputs, ... }:
+{
+  home-manager.users.rafiq = {
+    imports = [
+      inputs.nix-index-database.hmModules.nix-index
+    ];
+
+    programs.nix-index.enable = true;
+    programs.nix-index-database.comma.enable = true;
+  };
+}

configs/programs/default.nix

@@ -0,0 +1,27 @@
+{
+  imports = [
+    ./ags.nix
+    ./clipse.nix
+    ./comma.nix
+    ./zsh.nix
+    ./direnv.nix
+    ./dunst.nix
+    ./firefox.nix
+    ./fuzzel.nix
+    ./fzf.nix
+    ./getty.nix
+    ./git.nix
+    ./hyprland.nix
+    ./hyprlock.nix
+    ./hyprshade.nix
+    ./kitty.nix
+    ./nh.nix
+    ./nvf.nix
+    ./spicetify.nix
+    ./starship.nix
+    ./tealdeer.nix
+    ./yazi.nix
+    ./zellij.nix
+    ./zoxide.nix
+  ];
+}

configs/programs/direnv.nix

@@ -0,0 +1,12 @@
+{
+  # direnv lets us declare a .envrc in each project directory
+  # and updates the shell with the packages specified.
+
+  home-manager.users.rafiq = {
+    programs.direnv = {
+      enable = true;
+      enableBashIntegration = true;
+      nix-direnv.enable = true;
+    };
+  };
+}

configs/programs/dunst.nix

@@ -0,0 +1,5 @@
+{
+  home-manager.users.rafiq = {
+    services.dunst.enable = true;
+  };
+}

configs/programs/firefox.nix

@@ -0,0 +1,7 @@
+{
+  home-manager.users.rafiq = {
+    programs.firefox = {
+      enable = true;
+    };
+  };
+}

configs/programs/fuzzel.nix

@@ -0,0 +1,15 @@
+{
+  home-manager.users.rafiq = {
+    programs.fuzzel = {
+      enable = true;
+      settings = {
+        main = {
+          terminal = "kitty -1 -e";
+          layer = "top";
+          keyboard-focus = "on-demand";
+          list-executables-in-path = true;
+        };
+      };
+    };
+  };
+}

configs/programs/fzf.nix

@@ -0,0 +1,7 @@
+{
+  home-manager.users.rafiq = {
+    programs.fzf = {
+      enable = true;
+    };
+  };
+}

configs/programs/git.nix

@@ -0,0 +1,21 @@
+{ config, ... }:
+{
+  home-manager.users.rafiq = {
+    home.sessionVariables.GIT_CONFIG_GLOBAL = "$HOME/.config/git/config";
+
+    programs.git = {
+      enable = true;
+      userName = "Mohammad Rafiq";
+      userEmail = "mohammadrafiq567@gmail.com";
+      signing.key = "~/.ssh/id_ed25519.pub";
+      signing.signByDefault = true;
+      extraConfig = {
+        init.defaultBranch = "prime";
+        push.autoSetupRemote = true;
+        pull.rebase = false;
+        core.editor = "nvim";
+        gpg.format = "ssh";
+      };
+    };
+  };
+}

configs/programs/hyprland.nix

@@ -2,10 +2,134 @@
   inputs,
   pkgs,
   ...
-}: {
+}:
+{
   programs.hyprland = {
     enable = true;
     package = inputs.hyprland.packages.${pkgs.stdenv.hostPlatform.system}.hyprland;
-    portalPackage = inputs.hyprland.packages.${pkgs.stdenv.hostPlatform.system}.xdg-desktop-portal-hyprland;
+    portalPackage =
+      inputs.hyprland.packages.${pkgs.stdenv.hostPlatform.system}.xdg-desktop-portal-hyprland;
+  };
+
+  home-manager.users.rafiq = {
+    home.sessionVariables.NIXOS_OZONE_WL = "1";
+    wayland.windowManager.hyprland = {
+      enable = true;
+      package = null;
+      portalPackage = null;
+      settings = {
+        "$mainMonitor" = "desc:OOO AN-270W04K";
+        "$vertMonitor" = "desc:Philips Consumer Electronics Company PHL 246V5 AU11330000086";
+        "$mainMod" = "SUPER";
+        "$terminal" = "kitty -1";
+        "$multiplexer" = "$terminal -e zellij";
+        "$browser" = "firefox";
+        "$music" = "spotify";
+        "$launcher" = "fuzzel";
+        "$clipboard" = "$terminal --class clipse -e clipse";
+
+        # Programs to run at startup
+        exec-once = [
+          "hyprlock"
+          "clipse -listen"
+          "hyprcloser"
+        ];
+
+        env = [
+          "XCURSOR_SIZE,32"
+
+          # Nvidia Settings
+          "LIBVA_DRIVER_NAME,nvidia"
+          "__GLX_VENDOR_LIBRARY_NAME,nvidia"
+          "NVD_BACKEND,direct # needed for running vaapi-driver on later drivers"
+        ];
+
+        # Monitors
+        monitor = [
+          "$mainMonitor, 3840x2160@60, auto, auto"
+          "$vertMonitor, 1920x1080@60, auto-left, auto, transform, 3"
+          ", preferred, auto, 1"
+        ];
+
+        # Switching to the current workspace will switch to the previous
+        binds.workspace_back_and_forth = true;
+        cursor.default_monitor = "$mainMonitor";
+
+        # Windows
+        general = {
+          # Make there be no gaps in between windows or edges
+          border_size = 5;
+          gaps_in = 0;
+          gaps_out = 0;
+
+          resize_on_border = true;
+        };
+
+        windowrulev2 = [
+          "float, class:firefox, title:Picture-in-Picture"
+          "float, class:(clipse)"
+          "move cursor 0 0, class:(clipse)"
+          "size 622 652, class:(clipse)"
+          "noanim, class:(clipse)"
+        ];
+
+        animation = [
+          "workspaces, 0, , "
+        ];
+
+        # Keybinds
+        bind = [
+          "$mainMod, return, exec, $multiplexer"
+          "$mainMod, W, killactive"
+          "$mainMod, O, exec, $browser"
+          "$mainMod, Escape, exec, hyprlock"
+          "$mainMod, Space, exec, $launcher"
+
+          # Launch utilities
+          "$mainMod_SHIFT, A, exec, hyprpicker -a"
+          "$mainMod, V, exec, $clipboard"
+
+          # move between windows
+          "$mainMod, H, cyclenext, visible"
+          "$mainMod, L, cyclenext, visible prev"
+
+          # HJKL to move a window
+          "$mainMod_ALT, H, movewindow, l"
+          "$mainMod_ALT, J, movewindow, d"
+          "$mainMod_ALT, K, movewindow, u"
+          "$mainMod_ALT, L, movewindow, r"
+
+          # HJKL to resize a window
+          "ALT_SHIFT, H, resizeactive, -10% 0"
+          "ALT_SHIFT, J, resizeactive, 0 -10%"
+          "ALT_SHIFT, K, resizeactive, 0 10%"
+          "ALT_SHIFT, L, resizeactive, 10% 0"
+
+          # H and L to move between workspaces on the current monitor including creation
+          "$mainMod_CTRL, H, workspace, r-1"
+          "$mainMod_CTRL, L, workspace, r+1"
+        ];
+
+        # Repeat when held
+        bindle = [
+          # Keyboard Media Keys
+          ", XF86AudioRaiseVolume, exec, wpctl set-volume -l 1.5 @DEFAULT_AUDIO_SINK@ 5%+"
+          ", XF86AudioLowerVolume, exec, wpctl set-volume -l 1.5 @DEFAULT_AUDIO_SINK@ 5%-"
+        ];
+
+        bindm = [
+          "ALT, mouse:272, movewindow"
+        ];
+
+        input = {
+          numlock_by_default = true;
+          follow_mouse = 2; # Click on a window to change focus
+        };
+
+        debug = {
+          damage_tracking = 0;
+        };
+      };
+    };
   };
 }

configs/programs/hyprlock.nix

@@ -46,6 +46,7 @@ in
         };
 
         input-field = {
+          monitor = cfg.mainMonitor;
           fade_on_empty = true;
           size = "200, 45";
           halign = "center";

configs/programs/hyprshade.nix

@@ -0,0 +1,25 @@
+{ inputs, pkgs, ... }:
+{
+  home-manager.users.rafiq = {
+    home.packages = [ pkgs.hyprshade ];
+    xdg.configFile."hypr/hyprshade.toml" = {
+      enable = true;
+      text = # toml
+        ''
+          [[shades]]
+          name = "vibrance"
+          default = true  # will be activated when no other shader is scheduled
+
+          [[shades]]
+          name = "blue-light-filter"
+          start_time = 22:00:00
+          end_time = 08:00:00   # optional if more than one shader has start_time
+        '';
+    };
+    xdg.configFile."hypr/shaders" = {
+      enable = true;
+      recursive = true;
+      source = "${inputs.hyprshaders}/shaders";
+    };
+  };
+}

configs/programs/kitty.nix

@@ -0,0 +1,16 @@
+{
+  home-manager.users.rafiq = {
+    home.sessionVariables.TERMINAL = "kitty";
+    programs.kitty = {
+      enable = true;
+      keybindings = {
+        "ctrl+equal" = "change_font_size current +2.0";
+        "ctrl+minus" = "change_font_size current -2.0";
+      };
+      settings = {
+        window_padding_width = 10;
+        confirm_os_window_close = 0;
+      };
+    };
+  };
+}

configs/programs/nh.nix

@@ -0,0 +1,7 @@
+{
+  home-manager.users.rafiq = {
+    programs.nh = {
+      enable = true;
+    };
+  };
+}

configs/programs/nvf.nix

@@ -0,0 +1,88 @@
+{ inputs, pkgs, ... }:
+{
+  home-manager.users.rafiq = {
+    imports = [
+      inputs.nvf.homeManagerModules.default
+      ./nvf/input.nix
+      ./nvf/languages.nix
+      ./nvf/ui.nix
+      ./nvf/utilities.nix
+    ];
+    home.sessionVariables.EDITOR = "nvim";
+    programs.nvf = {
+      enable = true;
+      enableManpages = true;
+      settings.vim = {
+        viAlias = true;
+        vimAlias = true;
+        options = {
+          # Indentation
+          autoindent = true;
+          smartindent = true;
+          expandtab = true;
+          smarttab = true;
+          wrap = true;
+          shiftwidth = 2;
+          tabstop = 2;
+          foldlevel = 1000; # Open all folds by default
+
+          # Search
+          hlsearch = true;
+          ignorecase = true;
+          incsearch = true;
+          smartcase = true; # case-sensitive if search contains uppercase
+
+          # Visual
+          number = true;
+          cursorline = true;
+          visualbell = true;
+          termguicolors = true;
+
+          # Input
+          backspace = "indent,eol,start";
+        };
+        keymaps = [
+          {
+            desc = "Open the file path under the cursor, making the file if it doesn't exist.";
+            key = "gf";
+            mode = "n";
+            action = ":cd %:p:h<CR>:e <cfile><CR>";
+            silent = true;
+          }
+          {
+            desc = "Delete the previous word.";
+            key = "<C-BS>";
+            mode = "i";
+            action = "<C-W>";
+            silent = true;
+          }
+          {
+            desc = "Open the filetree.";
+            key = "t";
+            mode = "n";
+            action = ":Yazi<CR>";
+            silent = true;
+          }
+        ];
+        luaConfigRC.turn_off_inline_diagnostics =
+          # lua
+          ''
+            vim.diagnostic.config({
+              virtual_text = false -- turn off inline diagnostics
+            })
+          '';
+        extraPlugins = with pkgs.vimPlugins; {
+          yuck-vim = {
+            package = yuck-vim;
+          };
+          nvim-treesitter-parsers = {
+            package = nvim-treesitter-parsers.yuck;
+          };
+          nvim-parinfer = {
+            package = nvim-parinfer;
+          };
+        };
+      };
+    };
+  };
+}

configs/programs/nvf/input.nix

@@ -0,0 +1,69 @@
+{ lib, ... }:
+{
+  programs.nvf.settings.vim = {
+    autopairs.nvim-autopairs.enable = true;
+    snippets.luasnip = {
+      enable = true;
+      setupOpts.enable_autosnippets = true;
+    };
+    autocomplete = {
+      blink-cmp = {
+        enable = true;
+        friendly-snippets.enable = true;
+        setupOpts = {
+          enabled =
+            lib.generators.mkLuaInline
+              # lua
+              ''
+                --- Disable completion for markdown
+                function()
+                  return not vim.tbl_contains({"markdown"}, vim.bo.filetype)
+                    and vim.bo.buftype ~= "prompt"
+                    and vim.b.completion ~= false
+                end
+              '';
+          cmdline = {
+            enabled = true;
+            sources = null;
+            completion.menu.auto_show = false;
+          };
+          #completion.menu.auto_show =
+          #  lib.generators.mkLuaInline
+          #    # lua
+          #    ''
+          #      function(ctx)
+          #        --- Get the cursor position from the current window
+          #        local row, column = unpack(vim.api.nvim_win_get_cursor(0))
+          #        --- Get the current row (1 is Neovim API giving us 1-based indexing)
+          #        --- Get the current column but don't return negative numbers
+          #        --- ignore_injections are to ignore embedded code
+          #        --- success is the result, node is the syntax node object
+          #        local success, node = pcall(vim.treesitter.get_node, {
+          #          pos = {row - 1, math.max(0, column - 1)},
+          #          ignore_injections = false
+          #        })
+          #        --- Types of nodes to ignore
+          #        local reject = {"comment", "line_comment", "block_comment", "string_start", "string_content", "string_end" }
+          #        --- If the node type is in the reject table, don't show the completion
+          #        if success and node and vim.tbl_contains(reject, node:type()) then
+          #          return false;
+          #        end
+          #        -- whatever other logic you want beyond this
+          #        return true
+          #      end
+          #    '';
+          # menu.auto_show = false;
+          completion.documentation.auto_show_delay_ms = 0;
+          signature.enabled = true;
+        };
+      };
+    };
+    utility = {
+      motion = {
+        hop.enable = true; # <leader>h
+        precognition.enable = false;
+      };
+      yanky-nvim.enable = true;
+    };
+  };
+}

configs/programs/nvf/languages.nix

@@ -0,0 +1,19 @@
+{
+  programs.nvf.settings.vim.languages = {
+    # The below settings enable defaults for all languages
+    enableDAP = true;
+    enableExtraDiagnostics = true;
+    enableFormat = true;
+    enableLSP = true;
+    enableTreesitter = true;
+
+    # Enable specific languages
+    nix.enable = true;
+    nix.format.type = "nixfmt";
+    rust.enable = true;
+    clang.enable = true;
+    lua.enable = true;
+    python.enable = true;
+    css.enable = true;
+  };
+}

configs/programs/nvf/ui.nix

@@ -0,0 +1,52 @@
+{
+  programs.nvf.settings.vim = {
+    lsp = {
+      formatOnSave = true;
+      lightbulb.enable = true;
+      lspkind.enable = true;
+      otter-nvim.enable = true;
+      trouble.enable = true;
+    };
+    binds = {
+      cheatsheet.enable = true;
+      whichKey.enable = true;
+    };
+    debugger.nvim-dap = {
+      enable = true;
+      ui.enable = true;
+    };
+    notes.todo-comments.enable = true;
+    telescope.enable = true;
+    statusline.lualine.enable = true;
+    treesitter = {
+      enable = true;
+      autotagHtml = true;
+      fold = true;
+    };
+    notify.nvim-notify.enable = true;
+    visuals = {
+      fidget-nvim.enable = true;
+      indent-blankline.enable = true;
+      rainbow-delimiters.enable = true;
+      nvim-web-devicons.enable = true;
+      tiny-devicons-auto-colors.enable = true;
+    };
+    ui = {
+      borders.enable = true;
+      breadcrumbs.enable = true;
+      breadcrumbs.navbuddy.enable = true;
+      colorizer.enable = true;
+      noice.enable = true;
+      nvim-ufo.enable = true;
+    };
+    utility = {
+      ccc.enable = true;
+      images.image-nvim = {
+        enable = true;
+        setupOpts.backend = "kitty";
+      };
+      yazi-nvim.enable = true;
+      yazi-nvim.setupOpts.open_for_directories = true; # FIXME: does this work with neotree?
+    };
+  };
+}

configs/programs/nvf/utilities.nix

@@ -0,0 +1,22 @@
+{
+  programs.nvf.settings.vim = {
+    utility = {
+      direnv.enable = true;
+      nix-develop.enable = true;
+      leetcode-nvim = {
+        enable = true;
+        setupOpts = {
+          image_support = true; # requires image.nvim
+          lang = "rust";
+        };
+      };
+      mkdir.enable = true;
+      new-file-template = {
+        enable = true;
+        # add a directory containing lua/tempaltes/*.lua to vim.additionalRuntimePaths
+        # TODO: add for nix
+      };
+    };
+    session.nvim-session-manager.enable = true;
+  };
+}

configs/programs/spicetify.nix

@@ -0,0 +1,23 @@
+{
+  inputs,
+  pkgs,
+  ...
+}:
+let
+  spicePkgs = inputs.spicetify-nix.legacyPackages.${pkgs.stdenv.system};
+in
+{
+  home-manager.users.rafiq = {
+    imports = [
+      inputs.spicetify-nix.homeManagerModules.spicetify
+    ];
+    programs.spicetify = {
+      enable = true;
+      spotifyLaunchFlags = "--enable-features=UseOzonePlatform --ozone-platform=wayland";
+      windowManagerPatch = true;
+      enabledCustomApps = with spicePkgs.apps; [
+        marketplace
+      ];
+    };
+  };
+}

configs/programs/starship.nix

@@ -0,0 +1,16 @@
+{
+  home-manager.users.rafiq = {
+    programs.starship = {
+      enable = true;
+      settings = {
+        add_newline = false;
+        format = "$character";
+        right_format = "$all";
+        character = {
+          success_symbol = "[\\$](bold green)";
+          error_symbol = "[\\$](bold red)";
+        };
+      };
+    };
+  };
+}

configs/programs/tealdeer.nix

@@ -0,0 +1,8 @@
+{
+  home-manager.users.rafiq = {
+    programs.tealdeer = {
+      enable = true;
+      enableAutoUpdates = true;
+    };
+  };
+}

configs/programs/yazi.nix

@@ -0,0 +1,129 @@
+{
+  inputs,
+  pkgs,
+  ...
+}:
+let
+  yazi-plugins = pkgs.fetchFromGitHub {
+    owner = "yazi-rs";
+    repo = "plugins";
+    rev = "273019910c1111a388dd20e057606016f4bd0d17";
+    hash = "sha256-80mR86UWgD11XuzpVNn56fmGRkvj0af2cFaZkU8M31I=";
+  };
+in
+{
+  home-manager.users.rafiq = {
+    programs.yazi = {
+      enable = true;
+      package = inputs.yazi.packages.${pkgs.system}.default;
+      shellWrapperName = "y";
+      # yazi.toml
+      settings = {
+        manager = {
+          sort_by = "natural"; # Sort naturally, e.g. 1.md < 2.md < 10.md
+          sort_translit = true; # Transliterate filenames for sorting
+          show_hidden = true;
+        };
+        plugin = {
+          prepend_preloaders = [
+            {
+              mime = "{audio,video,image}/*";
+              run = "mediainfo";
+            }
+            {
+              mime = "application/subrip";
+              run = "mediainfo";
+            }
+          ];
+          prepend_previewers = [
+            {
+              name = "*.md";
+              run = "glow";
+            }
+            {
+              mime = "{audio,video,image}/*";
+              run = "mediainfo";
+            }
+            {
+              mime = "application/subrip";
+              run = "mediainfo";
+            }
+          ];
+          prepend_fetchers = [
+            {
+              id = "git";
+              name = "*";
+              run = "git";
+            }
+            {
+              id = "git";
+              name = "*/";
+              run = "git";
+            }
+          ];
+        };
+      };
+      # ~/.config/yazi/keymap.toml
+      keymap = {
+        manager.prepend_keymap = [
+          {
+            on = "l";
+            run = "plugin smart-enter";
+            desc = "Enter the child directory or open the file.";
+          }
+          {
+            on = "M";
+            run = "plugin mount";
+            desc = "Open the mount.yazi menu.";
+          }
+        ];
+      };
+      plugins = {
+        full-border = "${yazi-plugins}/full-border.yazi";
+        smart-enter = "${yazi-plugins}/smart-enter.yazi";
+        git = "${yazi-plugins}/git.yazi";
+        mount = "${yazi-plugins}/mount.yazi";
+        glow = pkgs.fetchFromGitHub {
+          owner = "Reledia";
+          repo = "glow.yazi";
+          rev = "c76bf4fb612079480d305fe6fe570bddfe4f99d3";
+          sha256 = "sha256-DPud1Mfagl2z490f5L69ZPnZmVCa0ROXtFeDbEegBBU=";
+        };
+        mediainfo = pkgs.fetchFromGitHub {
+          owner = "boydaihungst";
+          repo = "mediainfo.yazi";
+          rev = "447fe95239a488459cfdbd12f3293d91ac6ae0d7";
+          sha256 = "sha256-U6rr3TrFTtnibrwJdJ4rN2Xco4Bt4QbwEVUTNXlWRps=";
+        };
+        starship = pkgs.fetchFromGitHub {
+          owner = "Rolv-Apneseth";
+          repo = "starship.yazi";
+          rev = "6c639b474aabb17f5fecce18a4c97bf90b016512";
+          sha256 = "sha256-bhLUziCDnF4QDCyysRn7Az35RAy8ibZIVUzoPgyEO1A=";
+        };
+      };
+      initLua = ''
+        require("full-border"):setup()
+        require("git"):setup()
+        require("starship"):setup({
+          config_file = "${./yazi/starship.toml}",
+        })
+      '';
+    };
+    home.packages = with pkgs; [
+      jq # JSON preview
+      poppler_utils # PDF preview
+      _7zz # archive extraction and preview
+      ffmpeg
+      ffmpegthumbnailer # video thumbnails
+      fd # file searching
+      ripgrep # file content searching
+      fzf # quick file subtree navigation
+      zoxide # historical directories navigation
+      imagemagick # SVG, font, HEIC, JPEG preview
+      chafa # image/gif preview
+      glow # markdown preview
+      mediainfo # media metadata
+    ];
+  };
+}

configs/programs/yazi/starship.toml

@@ -0,0 +1 @@
+format = "$all"

configs/programs/zellij.nix

@@ -0,0 +1,14 @@
+{
+  home-manager.users.rafiq = {
+    programs.zellij = {
+      enable = true;
+      settings = {
+        mouse_mode = false;
+        keybinds.unbind = [
+          "Ctrl h"
+        ];
+      };
+    };
+    home.sessionVariables.ZELLIJ_AUTO_ATTACH = "true";
+  };
+}

configs/programs/zoxide.nix

@@ -0,0 +1,7 @@
+{
+  home-manager.users.rafiq = {
+    programs.zoxide = {
+      enable = true;
+    };
+  };
+}

configs/programs/zsh.nix

@@ -1,7 +1,41 @@
-{pkgs, ...}: {
+{
+  pkgs,
+  ...
+}:
+{
   programs.zsh = {
     enable = true;
   };
   users.defaultUserShell = pkgs.zsh;
-  environment.pathsToLink = ["/share/zsh"]; # enables completion
+  environment.pathsToLink = [ "/share/zsh" ]; # enables completion
+  home-manager.users.rafiq = {
+    programs.zsh = {
+      enable = true;
+      enableCompletion = true;
+      enableVteIntegration = true;
+      dirHashes = {
+        repos = "$HOME/GitRepos";
+        dl = "$HOME/Downloads";
+      };
+      initContent = # zsh
+        ''
+          # Bind CTRL+Backspace to delete whole word
+          bindkey '^H' backward-kill-word
+        '';
+      # TODO: Look into whether we need to add the history attribute
+      profileExtra = # bash
+        ''
+                if [ -z "$WAYLAND_DISPLAY" ] && [ "$XDG_VTNR" -eq 1 ]; then
+              dbus-run-session Hyprland
+          fi
+        '';
+      plugins = [
+        {
+          name = "vi-mode";
+          src = pkgs.zsh-vi-mode;
+          file = "share/zsh-vi-mode/zsh-vi-mode.plugin.zsh";
+        }
+      ];
+    };
+  };
 }