refactor(nixos): move hardware config options to machine nixos module

modules/nixos/machine/bootloader/default.nix

@@ -0,0 +1,30 @@
+{
+  config,
+  lib,
+  ...
+}:
+let
+  inherit (lib.pantheon) mkStrOption;
+  cfg = config.machine.bootloader;
+in
+{
+  options.machine.bootloader = {
+    type = mkStrOption;
+  };
+  config = lib.mkMerge [
+    {
+      boot.initrd.availableKernelModules = [
+        "nvme"
+        "xhci_pci"
+        "ahci"
+        "usbhid"
+        "usb_storage"
+        "sd_mod"
+      ];
+      boot.loader.efi.canTouchEfiVariables = true;
+    }
+    (lib.mkIf (config.machine.bootloader.type == "systemd-boot") {
+      boot.loader.systemd-boot.enable = true;
+    })
+  ];
+}

modules/nixos/machine/default.nix

@@ -0,0 +1,19 @@
+{ lib, modulesPath, ... }:
+let
+  inherit (lib) singleton;
+in
+{
+  imports = [
+    (modulesPath + "/installer/scan/not-detected.nix")
+  ];
+
+  config = {
+    services.fwupd.enable = true;
+    persistDirs = singleton "/var/lib/bluetooth";
+    hardware.bluetooth = {
+      enable = true;
+      settings.General.Experimental = true;
+    };
+    hardware.xone.enable = true;
+  };
+}

modules/nixos/machine/drives/btrfs/default.nix

@@ -0,0 +1,107 @@
+{ config, lib, ... }:
+let
+  inherit (lib) mkIf mkEnableOption;
+  inherit (lib.pantheon) mkStrOption;
+  cfg = config.machine.drives.btrfs;
+  ephemeralRootCfg = {
+    boot.initrd.postDeviceCommands = lib.mkAfter ''
+      	    mkdir /btrfs_tmp
+      	    mount /dev/root_vg/root /btrfs_tmp
+      	    if [[ -e /btrfs_tmp/root ]]; then
+      		mkdir -p /btrfs_tmp/old_roots
+      		timestamp=$(date --date="@$(stat -c %Y /btrfs_tmp/root)" "+%Y-%m-%-d_%H:%M:%S")
+      		mv /btrfs_tmp/root "/btrfs_tmp/old_roots/$timestamp"
+      	    fi
+
+      	    delete_subvolume_recursively() {
+      		IFS=$'\n'
+      		for i in $(btrfs subvolume list -o "$1" | cut -f 9- -d ' '); do
+      		    delete_subvolume_recursively "/btrfs_tmp/$i"
+      		done
+      		btrfs subvolume delete "$1"
+      	    }
+
+      	    for i in $(find /btrfs_tmp/old_roots/ -maxdepth 1 -mtime +30); do
+      		delete_subvolume_recursively "$i"
+      	    done
+
+      	    btrfs subvolume create /btrfs_tmp/root
+      	    umount /btrfs_tmp
+      	  '';
+    programs.fuse.userAllowOther = true;
+    fileSystems."/persist".neededForBoot = true;
+    #FIXME: below should be in module or something
+    environment.persistence."/persist" = {
+      hideMounts = true;
+      files = [
+        "/etc/ssh/ssh_host_ed25519_key"
+        "/etc/ssh/ssh_host_ed25519_key.pub"
+        "/etc/ssh/ssh_host_rsa_key"
+        "/etc/ssh/ssh_host_rsa_key.pub"
+        "/etc/machine-id"
+      ];
+    };
+  };
+in
+{
+  options.machine.drives.btrfs = {
+    enable = mkEnableOption "";
+    drive = mkStrOption;
+    ephemeralRoot = mkEnableOption "";
+  };
+  config = mkIf cfg.enable (
+    {
+      boot.initrd.kernelModules = [ "dm-snapshot" ];
+      disko.devices.disk.main = {
+        device = cfg.drive;
+        type = "disk";
+        content.type = "gpt";
+        content.partitions = {
+          boot.name = "boot";
+          boot.size = "1M";
+          boot.type = "EF02";
+          esp.name = "ESP";
+          esp.size = "500M";
+          esp.type = "EF00";
+          esp.content = {
+            type = "filesystem";
+            format = "vfat";
+            mountpoint = "/boot";
+          };
+          swap.size = "4G";
+          swap.content = {
+            type = "swap";
+            resumeDevice = true;
+          };
+          root.name = "root";
+          root.size = "100%";
+          root.content = {
+            type = "lvm_pv";
+            vg = "root_vg";
+          };
+        };
+      };
+
+      disko.devices.lvm_vg.root_vg = {
+        type = "lvm_vg";
+        lvs.root.size = "100%FREE";
+        lvs.root.content.type = "btrfs";
+        lvs.root.content.extraArgs = [ "-f" ];
+        lvs.root.content.subvolumes = {
+          "/root".mountpoint = "/";
+          "/persist".mountpoint = "/persist";
+          "/persist".mountOptions = [
+            "subvol=persist"
+            "noatime"
+          ];
+          "/nix".mountpoint = "/nix";
+          "/nix".mountOptions = [
+            "subvol=nix"
+            "noatime"
+          ];
+        };
+      };
+    }
+    // ephemeralRootCfg
+  );
+}

modules/nixos/machine/gpu/default.nix

@@ -0,0 +1,41 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+let
+  inherit (lib)
+    mkMerge
+    mkIf
+    mkEnableOption
+    singleton
+    ;
+  cfg = config.machine.gpu;
+in
+{
+  options.machine.gpu = {
+    nvidia.enable = mkEnableOption "";
+  };
+  config = mkMerge [
+    (mkIf cfg.nvidia.enable {
+      hardware = {
+        graphics.enable = true;
+        graphics.extraPackages = singleton pkgs.nvidia-vaapi-driver;
+        nvidia.open = true;
+        nvidia.package = config.boot.kernelPackages.nvidiaPackages.latest;
+      };
+      services.xserver.videoDrivers = [ "nvidia" ];
+      nixpkgs.config.allowUnfree = true;
+      environment.variables = {
+        LIBVA_DRIVER_NAME = "nvidia";
+        __GLX_VENDOR_LIBRARY_NAME = "nvidia";
+        NVD_BACKEND = "direct";
+      };
+      nix.settings.substituters = [ "https://cuda-maintainers.cachix.org" ];
+      nix.settings.trusted-public-keys = [
+        "cuda-maintainers.cachix.org-1:0dq3bujKpuEPMCX6U4WylrUDZ9JyUG0VpVZa7CNfq5E="
+      ];
+    })
+  ];
+}

modules/nixos/machine/platform/default.nix

@@ -0,0 +1,21 @@
+{ config, lib, ... }:
+let
+  inherit (lib) singleton mkOption;
+  inherit (lib.types) enum;
+  cfg = config.machine.platform;
+in
+{
+  options.machine.platform = {
+    type = mkOption {
+      type = enum [
+        "amd"
+        "intel"
+      ];
+    };
+  };
+
+  config = {
+    hardware.cpu.${cfg.type}.updateMicrocode = true;
+    boot.kernelModules = singleton "kvm-${cfg.type}";
+  };
+}

modules/nixos/machine/usb/default.nix

@@ -0,0 +1,46 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}:
+let
+  inherit (lib)
+    mkEnableOption
+    mkIf
+    mkMerge
+    singleton
+    ;
+  cfg = config.machine.usb;
+in
+{
+  options.machine.usb = {
+    automount = mkEnableOption "";
+    enableQmk = mkEnableOption "";
+  };
+
+  config = mkMerge [
+    (mkIf cfg.automount {
+      services.udisks2.enable = true;
+      home-manager.sharedModules = singleton {
+        services.udiskie = {
+          enable = true;
+          automount = true;
+          notify = true;
+        };
+      };
+    })
+    (mkIf cfg.enableQmk {
+      hardware.keyboard.qmk.enable = true;
+      services.udev = {
+        packages = with pkgs; [
+          vial
+          via
+          qmk
+          qmk-udev-rules
+          qmk_hid
+        ];
+      };
+    })
+  ];
+}