{
  inputs,
  lib,
  hostname,
  type,
  modulesPath,
  ...
}:
{
  imports = builtins.concatLists [
    # Common options for all machines.
    [
      (modulesPath + "/installer/scan/not-detected.nix")
      ./boot.nix
      ./networking.nix
      ./nix-config.nix
      ./security.nix
      ./shell
      ./users.nix
    ]
    # Options for graphical systems.
    (lib.optionals (type == "desktop") [
      ./graphical
      ./hardware/audio.nix
      ./hardware/bluetooth.nix
      ./stylix.nix
    ])
    # Options for specific hostnames.
    (lib.optionals (hostname == "nemesis") [
      ./bootloaders/systemd-boot.nix
      ./filesystems/hw-nemesis.nix
      ./hardware/cpu_amd.nix
      ./hardware/nvidia.nix
    ])
    (lib.optionals (hostname == "mellinoe") [
      ./bootloaders/systemd-boot.nix
      (import ./filesystems/impermanence.nix {
        inherit inputs lib;
        device = "/dev/disk/by-id/nvme-eui.01000000000000008ce38e04019a68ab";
      })
      ./hardware/cpu_intel.nix
    ])
  ];
}